4173e8695a
I have also updated the dependencies for bitcoin: * qt4 is updated to qt5 * miniupnpc 1 is updated to miniupnpc 2 * zeromq dependency has been added to enable ZeroMQ support.
41 lines
1.7 KiB
Nix
41 lines
1.7 KiB
Nix
{ stdenv, fetchurl, pkgconfig, autoreconfHook, openssl, db48, boost, zeromq
|
|
, zlib, miniupnpc, qtbase ? null, qttools ? null, utillinux, protobuf, qrencode, libevent
|
|
, withGui }:
|
|
|
|
with stdenv.lib;
|
|
stdenv.mkDerivation rec{
|
|
name = "bitcoin" + (toString (optional (!withGui) "d")) + "-" + version;
|
|
version = "0.15.1";
|
|
|
|
src = fetchurl {
|
|
urls = [ "https://bitcoincore.org/bin/bitcoin-core-${version}/bitcoin-${version}.tar.gz"
|
|
"https://bitcoin.org/bin/bitcoin-core-${version}/bitcoin-${version}.tar.gz"
|
|
];
|
|
sha256 = "1d22fgwdcn343kd95lh389hj417zwbmnhi29cij8n7wc0nz2vpil";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig autoreconfHook ];
|
|
buildInputs = [ openssl db48 boost zlib zeromq
|
|
miniupnpc protobuf libevent]
|
|
++ optionals stdenv.isLinux [ utillinux ]
|
|
++ optionals withGui [ qtbase qttools qrencode ];
|
|
|
|
configureFlags = [ "--with-boost-libdir=${boost.out}/lib" ]
|
|
++ optionals withGui [ "--with-gui=qt5"
|
|
"--with-qt-bindir=${qtbase.dev}/bin:${qttools.dev}/bin"
|
|
];
|
|
|
|
meta = {
|
|
description = "Peer-to-peer electronic cash system";
|
|
longDescription= ''
|
|
Bitcoin is a free open source peer-to-peer electronic cash system that is
|
|
completely decentralized, without the need for a central server or trusted
|
|
parties. Users hold the crypto keys to their own money and transact directly
|
|
with each other, with the help of a P2P network to check for double-spending.
|
|
'';
|
|
homepage = http://www.bitcoin.org/;
|
|
maintainers = with maintainers; [ roconnor AndersonTorres ];
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|