7bbb1ad569
handling of dynamic libraries from --copy-dt-needed-entries to --no-copy-dt-needed-entries, which breaks stuff (e.g. GCC, see http://hydra.nixos.org/build/1608471). So stick with 2.21.1 for now. svn path=/nixpkgs/branches/stdenv-updates/; revision=30870
82 lines
3.3 KiB
Nix
82 lines
3.3 KiB
Nix
{ stdenv, fetchurl, noSysDirs, zlib, cross ? null, gold ? false, bison ? null, flex2535 ? null, bc ? null, dejagnu ? null }:
|
|
|
|
let basename = "binutils-2.21.1a"; in
|
|
stdenv.mkDerivation rec {
|
|
name = basename + stdenv.lib.optionalString (cross != null) "-${cross.config}";
|
|
|
|
# WARNING: Upstream made a mistake in packaging that may mean anyone
|
|
# but the FSF hosting this tarball is accidentally in violation of
|
|
# the GPL. We can't update binutils until the next stdenv-updates,
|
|
# so we are stuck with this version. The issue is discussed in
|
|
# this email: http://sourceware.org/ml/binutils/2011-08/msg00198.html
|
|
# The tarball for this minor version will not be fixed, as only the
|
|
# tarballs for the latest minor version of each major version will
|
|
# be repackaged. The fixed sources for the closest version to this one
|
|
# can be found at mirror://gnu/binutils/binutils-2.21.1a.tar.bz2
|
|
# or http://ftp.gnu.org/gnu/binutils/binutils-2.21.1a.tar.bz2
|
|
# The sources missing from this tarball come from cgen. It is unclear
|
|
# WHICH sources should be included, but the cvs tree can be checked out
|
|
# by:
|
|
# cvs -z 9 -d :pserver:anoncvs@sourceware.org:/cvs/src login
|
|
# {enter "anoncvs" as the password}
|
|
# cvs -z 9 -d :pserver:anoncvs@sourceware.org:/cvs/src co cgen
|
|
src = fetchurl {
|
|
url = "mirror://gnu/binutils/${basename}.tar.bz2";
|
|
sha256 = "0m7nmd7gc9d9md43wbrv65hz6lbi2crqwryzpigv19ray1lzmv6d";
|
|
};
|
|
|
|
patches = [
|
|
# Turn on --enable-new-dtags by default to make the linker set
|
|
# RUNPATH instead of RPATH on binaries. This is important because
|
|
# RUNPATH can be overriden using LD_LIBRARY_PATH at runtime.
|
|
./new-dtags.patch
|
|
];
|
|
|
|
buildInputs =
|
|
[ zlib ]
|
|
++ stdenv.lib.optional gold [dejagnu flex2535 bison /* Some Gold tests require this: */ bc];
|
|
|
|
inherit noSysDirs;
|
|
|
|
preConfigure = ''
|
|
# Clear the default library search path.
|
|
if test "$noSysDirs" = "1"; then
|
|
echo 'NATIVE_LIB_DIRS=' >> ld/configure.tgt
|
|
fi
|
|
|
|
# Use symlinks instead of hard links to save space ("strip" in the
|
|
# fixup phase strips each hard link separately).
|
|
for i in binutils/Makefile.in gas/Makefile.in ld/Makefile.in; do
|
|
substituteInPlace $i --replace 'ln ' 'ln -s '
|
|
done
|
|
'';
|
|
|
|
# As binutils takes part in the stdenv building, we don't want references
|
|
# to the bootstrap-tools libgcc (as uses to happen on arm/mips)
|
|
NIX_CFLAGS_COMPILE = "-static-libgcc";
|
|
|
|
configureFlags = "--disable-werror" # needed for dietlibc build
|
|
+ stdenv.lib.optionalString (stdenv.system == "mips64-linux")
|
|
" --enable-fix-loongson2f-nop"
|
|
+ stdenv.lib.optionalString (cross != null) " --target=${cross.config}"
|
|
+ stdenv.lib.optionalString gold " --enable-gold";
|
|
|
|
meta = {
|
|
description = "GNU Binutils, tools for manipulating binaries (linker, assembler, etc.)";
|
|
|
|
longDescription = ''
|
|
The GNU Binutils are a collection of binary tools. The main
|
|
ones are `ld' (the GNU linker) and `as' (the GNU assembler).
|
|
They also include the BFD (Binary File Descriptor) library,
|
|
`gprof', `nm', `strip', etc.
|
|
'';
|
|
|
|
homepage = http://www.gnu.org/software/binutils/;
|
|
|
|
license = "GPLv3+";
|
|
|
|
/* Give binutils a lower priority than gcc-wrapper to prevent a
|
|
collision due to the ld/as wrappers/symlinks in the latter. */
|
|
priority = "10";
|
|
};
|
|
}
|