86 lines
2.9 KiB
Nix
86 lines
2.9 KiB
Nix
{ stdenv, libXScrnSaver, makeWrapper, fetchurl, wrapGAppsHook, gtk3, unzip, atomEnv, libuuid, at-spi2-atk }:
|
|
|
|
let
|
|
version = "4.1.5";
|
|
name = "electron-${version}";
|
|
|
|
throwSystem = throw "Unsupported system: ${stdenv.hostPlatform.system}";
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Cross platform desktop application shell";
|
|
homepage = https://github.com/electron/electron;
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ travisbhartwell manveru ];
|
|
platforms = [ "x86_64-darwin" "x86_64-linux" "i686-linux" "armv7l-linux" "aarch64-linux" ];
|
|
};
|
|
|
|
linux = {
|
|
inherit name version meta;
|
|
src = {
|
|
i686-linux = fetchurl {
|
|
url = "https://github.com/electron/electron/releases/download/v${version}/electron-v${version}-linux-ia32.zip";
|
|
sha256 = "0rqaydlg7wkccks7crwpylad0bsz8knm82mpb7hnj68p9njxpsbz";
|
|
};
|
|
x86_64-linux = fetchurl {
|
|
url = "https://github.com/electron/electron/releases/download/v${version}/electron-v${version}-linux-x64.zip";
|
|
sha256 = "0xwvn41pvpsrx54waix8kmg3w1f1f9nmfn08hf9bkgnlgh251shy";
|
|
};
|
|
armv7l-linux = fetchurl {
|
|
url = "https://github.com/electron/electron/releases/download/v${version}/electron-v${version}-linux-armv7l.zip";
|
|
sha256 = "172yq2m4i0pf72xr6w3xgkxfakkx2wrc54aah5j3nr6809bcnzji";
|
|
};
|
|
aarch64-linux = fetchurl {
|
|
url = "https://github.com/electron/electron/releases/download/v${version}/electron-v${version}-linux-arm64.zip";
|
|
sha256 = "0gcgvgplg9c2sm53sa4nll4x486c4m190ma9a98xfx9mp9vy55vq";
|
|
};
|
|
}.${stdenv.hostPlatform.system} or throwSystem;
|
|
|
|
buildInputs = [ gtk3 ];
|
|
|
|
nativeBuildInputs = [
|
|
unzip
|
|
makeWrapper
|
|
wrapGAppsHook
|
|
];
|
|
|
|
dontWrapGApps = true; # electron is in lib, we need to wrap it manually
|
|
|
|
buildCommand = ''
|
|
mkdir -p $out/lib/electron $out/bin
|
|
unzip -d $out/lib/electron $src
|
|
ln -s $out/lib/electron/electron $out/bin
|
|
|
|
fixupPhase
|
|
|
|
patchelf \
|
|
--set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
--set-rpath "${atomEnv.libPath}:${stdenv.lib.makeLibraryPath [ libuuid at-spi2-atk ]}:$out/lib/electron" \
|
|
$out/lib/electron/electron
|
|
|
|
wrapProgram $out/lib/electron/electron \
|
|
--prefix LD_PRELOAD : ${stdenv.lib.makeLibraryPath [ libXScrnSaver ]}/libXss.so.1 \
|
|
"''${gappsWrapperArgs[@]}"
|
|
'';
|
|
};
|
|
|
|
darwin = {
|
|
inherit name version meta;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/electron/electron/releases/download/v${version}/electron-v${version}-darwin-x64.zip";
|
|
sha256 = "1z43ga620rw84x1yxvnxf11pd782s5vgj5dgnn4k0nfgxlihy058";
|
|
};
|
|
|
|
buildInputs = [ unzip ];
|
|
|
|
buildCommand = ''
|
|
mkdir -p $out/Applications
|
|
unzip $src
|
|
mv Electron.app $out/Applications
|
|
mkdir -p $out/bin
|
|
ln -s $out/Applications/Electron.app/Contents/MacOs/Electron $out/bin/electron
|
|
'';
|
|
};
|
|
in
|
|
|
|
stdenv.mkDerivation (if stdenv.isDarwin then darwin else linux)
|