88c9f8b574
This seems to have been confusing people, using both xlibs and xorg, etc. - Avoided renaming local (and different) xlibs binding in gcc*. - Fixed cases where both xorg and xlibs were used. Hopefully everything still works as before.
74 lines
2.6 KiB
Nix
74 lines
2.6 KiB
Nix
{ stdenv, fetchurl, buildEnv
|
|
, xorg, alsaLib, dbus, dbus_glib, glib, gtk, atk, pango, freetype, fontconfig
|
|
, gdk_pixbuf, cairo, zlib}:
|
|
let
|
|
bits = if stdenv.system == "x86_64-linux" then "64"
|
|
else "32";
|
|
|
|
# isolated tor environment
|
|
torEnv = buildEnv {
|
|
name = "tor-env";
|
|
paths = [
|
|
stdenv.cc.cc zlib glib alsaLib dbus dbus_glib gtk atk pango freetype
|
|
fontconfig gdk_pixbuf cairo xorg.libXrender xorg.libX11 xorg.libXext
|
|
xorg.libXt
|
|
];
|
|
};
|
|
|
|
ldLibraryPath = if bits == "64" then torEnv+"/lib:"+torEnv+"/lib64"
|
|
else torEnv+"/lib";
|
|
|
|
in stdenv.mkDerivation rec {
|
|
name = "tor-browser-${version}";
|
|
version = "4.5.3";
|
|
|
|
src = fetchurl {
|
|
url = "https://archive.torproject.org/tor-package-archive/torbrowser/${version}/tor-browser-linux${bits}-${version}_en-US.tar.xz";
|
|
sha256 = if bits == "64" then
|
|
"24c517d2aeb15ba5eeda1eb87f483ed4fb0c22b07a95ca26af9f692e0d4d9b7c" else
|
|
"154d659583048e91870c40921561f0519babf6d3c9ac439f6fb74ed66824463f";
|
|
};
|
|
|
|
patchPhase = ''
|
|
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" Browser/firefox
|
|
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" Browser/TorBrowser/Tor/tor
|
|
'';
|
|
|
|
doCheck = true;
|
|
checkPhase = ''
|
|
# Just do a simple test if all libraries get loaded by running help on
|
|
# firefox and tor
|
|
echo "Checking firefox..."
|
|
LD_LIBRARY_PATH=${ldLibraryPath} Browser/firefox --help 1> /dev/null
|
|
echo "Checking tor..."
|
|
LD_LIBRARY_PATH=${torEnv}/lib:Browser/TorBrowser/Tor Browser/TorBrowser/Tor/tor --help 1> /dev/null
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/share/tor-browser
|
|
mkdir -p $out/bin
|
|
cp -R * $out/share/tor-browser
|
|
|
|
cat > "$out/bin/tor-browser" << EOF
|
|
export HOME="\$HOME/.torbrowser4"
|
|
if [ ! -d \$HOME ]; then
|
|
mkdir -p \$HOME && cp -R $out/share/tor-browser/Browser/TorBrowser/Data \$HOME/ && chmod -R +w \$HOME
|
|
echo "pref(\"extensions.torlauncher.tordatadir_path\", \"\$HOME/Data/Tor/\");" >> \
|
|
~/Data/Browser/profile.default/preferences/extension-overrides.js
|
|
fi
|
|
export LD_LIBRARY_PATH=${ldLibraryPath}:$out/share/tor-browser/Browser/TorBrowser/Tor
|
|
$out/share/tor-browser/Browser/firefox -no-remote -profile ~/Data/Browser/profile.default "$@"
|
|
EOF
|
|
chmod +x $out/bin/tor-browser
|
|
'';
|
|
|
|
buildInputs = [ stdenv ];
|
|
|
|
meta = {
|
|
description = "Tor Browser Bundle";
|
|
homepage = https://www.torproject.org/;
|
|
platforms = stdenv.lib.platforms.linux;
|
|
maintainers = with stdenv.lib.maintainers;
|
|
[ offline matejc doublec thoughtpolice ];
|
|
};
|
|
}
|