bf762d13e3
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/dbus/versions. These checks were done: - built on NixOS - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-monitor --help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-update-activation-environment help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-cleanup-sockets -h’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-cleanup-sockets --help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-cleanup-sockets help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-run-session -h’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-run-session --help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-uuidgen --help’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-launch -h’ got 0 exit code - ran ‘/nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8/bin/dbus-launch --help’ got 0 exit code - found 1.12.8 with grep in /nix/store/q2p724wzbngs5qrv96s2mny5bhsnm3jk-dbus-1.12.8 - directory tree listing: https://gist.github.com/598fa486a7a2da2a0887e0899dd2ed27
92 lines
3.2 KiB
Nix
92 lines
3.2 KiB
Nix
{ stdenv, lib, fetchurl, pkgconfig, expat, systemd
|
|
, libX11 ? null, libICE ? null, libSM ? null, x11Support ? (stdenv.isLinux || stdenv.isDarwin) }:
|
|
|
|
assert x11Support -> libX11 != null
|
|
&& libICE != null
|
|
&& libSM != null;
|
|
|
|
let
|
|
version = "1.12.8";
|
|
sha256 = "1cvfi7jiby12h0f5gbysphhk99m6mch87ab3cqxkj0w36gkrkp72";
|
|
|
|
self = stdenv.mkDerivation {
|
|
name = "dbus-${version}";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "http://dbus.freedesktop.org/releases/dbus/dbus-${version}.tar.gz";
|
|
inherit sha256;
|
|
};
|
|
|
|
patches = lib.optional stdenv.isSunOS ./implement-getgrouplist.patch;
|
|
postPatch = ''
|
|
substituteInPlace tools/Makefile.in \
|
|
--replace 'install-localstatelibDATA:' 'disabled:' \
|
|
--replace 'install-data-local:' 'disabled:' \
|
|
--replace 'installcheck-local:' 'disabled:'
|
|
substituteInPlace bus/Makefile.in \
|
|
--replace '$(mkinstalldirs) $(DESTDIR)$(localstatedir)/run/dbus' ':'
|
|
'' + /* cleanup of runtime references */ ''
|
|
substituteInPlace ./dbus/dbus-sysdeps-unix.c \
|
|
--replace 'DBUS_BINDIR "/dbus-launch"' "\"$lib/bin/dbus-launch\""
|
|
substituteInPlace ./tools/dbus-launch.c \
|
|
--replace 'DBUS_DAEMONDIR"/dbus-daemon"' '"/run/current-system/sw/bin/dbus-daemon"'
|
|
'';
|
|
|
|
outputs = [ "out" "dev" "lib" "doc" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
propagatedBuildInputs = [ expat ];
|
|
buildInputs = lib.optional stdenv.isLinux systemd
|
|
++ lib.optionals x11Support [ libX11 libICE libSM ];
|
|
# ToDo: optional selinux?
|
|
|
|
configureFlags = [
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--with-session-socket-dir=/tmp"
|
|
"--with-system-pid-file=/run/dbus/pid"
|
|
"--with-system-socket=/run/dbus/system_bus_socket"
|
|
"--with-systemdsystemunitdir=$(out)/etc/systemd/system"
|
|
"--with-systemduserunitdir=$(out)/etc/systemd/user"
|
|
"--enable-user-session"
|
|
"--datadir=/etc"
|
|
"--libexecdir=$(out)/libexec"
|
|
] ++ lib.optional (!x11Support) "--without-x";
|
|
|
|
# Enable X11 autolaunch support in libdbus. This doesn't actually depend on X11
|
|
# (it just execs dbus-launch in dbus.tools), contrary to what the configure script demands.
|
|
# problems building without x11Support so disabled in that case for now
|
|
NIX_CFLAGS_COMPILE = lib.optionalString x11Support "-DDBUS_ENABLE_X11_AUTOLAUNCH=1";
|
|
NIX_CFLAGS_LINK = lib.optionalString (!stdenv.isDarwin) "-Wl,--as-needed";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = true;
|
|
|
|
installFlags = [ "sysconfdir=$(out)/etc" "datadir=$(out)/share" ];
|
|
|
|
postInstall = ''
|
|
mkdir -p "$out/share/xml/dbus"
|
|
cp doc/*.dtd "$out/share/xml/dbus"
|
|
'';
|
|
|
|
# it's executed from $lib by absolute path
|
|
postFixup = ''
|
|
moveToOutput bin/dbus-launch "$lib"
|
|
ln -s "$lib/bin/dbus-launch" "$out/bin/"
|
|
'';
|
|
|
|
passthru = {
|
|
dbus-launch = "${self.lib}/bin/dbus-launch";
|
|
daemon = self.out;
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Simple interprocess messaging system";
|
|
homepage = http://www.freedesktop.org/wiki/Software/dbus/;
|
|
license = licenses.gpl2Plus; # most is also under AFL-2.1
|
|
platforms = platforms.unix;
|
|
};
|
|
};
|
|
in self
|