6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
67 lines
1.6 KiB
Nix
67 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.fonts.fontDir;
|
|
|
|
x11Fonts = pkgs.runCommand "X11-fonts" { preferLocalBuild = true; } ''
|
|
mkdir -p "$out/share/X11/fonts"
|
|
font_regexp='.*\.\(ttf\|ttc\|otb\|otf\|pcf\|pfa\|pfb\|bdf\)\(\.gz\)?'
|
|
find ${toString config.fonts.packages} -regex "$font_regexp" \
|
|
-exec ln -sf -t "$out/share/X11/fonts" '{}' \;
|
|
cd "$out/share/X11/fonts"
|
|
${optionalString cfg.decompressFonts ''
|
|
${pkgs.gzip}/bin/gunzip -f *.gz
|
|
''}
|
|
${pkgs.xorg.mkfontscale}/bin/mkfontscale
|
|
${pkgs.xorg.mkfontdir}/bin/mkfontdir
|
|
cat $(find ${pkgs.xorg.fontalias}/ -name fonts.alias) >fonts.alias
|
|
'';
|
|
|
|
in
|
|
|
|
{
|
|
|
|
options = {
|
|
fonts.fontDir = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to create a directory with links to all fonts in
|
|
{file}`/run/current-system/sw/share/X11/fonts`.
|
|
'';
|
|
};
|
|
|
|
decompressFonts = mkOption {
|
|
type = types.bool;
|
|
default = config.programs.xwayland.enable;
|
|
defaultText = literalExpression "config.programs.xwayland.enable";
|
|
description = ''
|
|
Whether to decompress fonts in
|
|
{file}`/run/current-system/sw/share/X11/fonts`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
environment.systemPackages = [ x11Fonts ];
|
|
environment.pathsToLink = [ "/share/X11/fonts" ];
|
|
|
|
services.xserver.filesSection = ''
|
|
FontPath "${x11Fonts}/share/X11/fonts"
|
|
'';
|
|
|
|
};
|
|
|
|
imports = [
|
|
(mkRenamedOptionModule [ "fonts" "enableFontDir" ] [ "fonts" "fontDir" "enable" ])
|
|
];
|
|
|
|
}
|