ac8fadc7f3
* colima: use updated Makefile in build and install phases * colima: use lima-unwrapped * colima: fix dynamic version * colima: 0.4.2 -> 0.4.3 * colima: delete .git folder in postfetch when `leaveDotGit = true` Otherwise it may lead to non-deterministic behaviour. Co-authored-by: j-k <dev@j-k.io> * colima: do not override default buildGoModule phases The colima Makefile does more or less the same as the `buildGoModule` implementation. Instead of overriding it and using the Makefile directly, we reproduce the behaviour desired behaviour by customising env variables, e.g. `ldflags` and `subPackages`. Co-authored-by: j-k <dev@j-k.io> * colima: use `buildGoModule = buildGo118Module;` Co-authored-by: j-k <dev@j-k.io> * colima: update meta.description Co-authored-by: j-k <dev@j-k.io> * colima: set `CGO_ENABLED = 1` to make VPN connections work See https://github.com/abiosoft/colima/issues/358 * colima: 0.4.3 -> 0.4.4 * colima: define all ldflags in preConfigure Co-authored-by: Atemu <Atemu@users.noreply.github.com> * colima: add version test * colima: add meta.mainProgram and meta.platforms * colima: remove unused runCommand input Co-authored-by: j-k <dev@j-k.io> * colima: cleanup meta Co-authored-by: Sandro <sandro.jaeckel@gmail.com> * colima: drop meta.platforms because we use the default value of `platforms.darwin ++ platforms.linux` Co-authored-by: Sandro <sandro.jaeckel@gmail.com> Co-authored-by: Atemu <Atemu@users.noreply.github.com> * Update pkgs/applications/virtualization/colima/default.nix Co-authored-by: j-k <dev@j-k.io> Co-authored-by: Atemu <Atemu@users.noreply.github.com> Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
63 lines
1.5 KiB
Nix
63 lines
1.5 KiB
Nix
{ lib
|
|
, buildGoModule
|
|
, fetchFromGitHub
|
|
, installShellFiles
|
|
, lima
|
|
, makeWrapper
|
|
, qemu
|
|
, testers
|
|
, colima
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "colima";
|
|
version = "0.4.4";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "abiosoft";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "bSBaSS+rVkFqTSdyegdE/F0X5u7yvF/nHslAO3xgD6I=";
|
|
# We need the git revision
|
|
leaveDotGit = true;
|
|
postFetch = ''
|
|
git -C $out rev-parse --short HEAD > $out/.git-revision
|
|
rm -rf $out/.git
|
|
'';
|
|
};
|
|
|
|
nativeBuildInputs = [ installShellFiles makeWrapper ];
|
|
|
|
vendorSha256 = "sha256-jDzDwK7qA9lKP8CfkKzfooPDrHuHI4OpiLXmX9vOpOg=";
|
|
|
|
CGO_ENABLED = 1;
|
|
|
|
preConfigure = ''
|
|
ldflags="-s -w -X github.com/abiosoft/colima/config.appVersion=${version} \
|
|
-X github.com/abiosoft/colima/config.revision=$(cat .git-revision)"
|
|
'';
|
|
|
|
subPackages = [ "cmd/colima" ];
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/colima \
|
|
--prefix PATH : ${lib.makeBinPath [ lima qemu ]}
|
|
|
|
installShellCompletion --cmd colima \
|
|
--bash <($out/bin/colima completion bash) \
|
|
--fish <($out/bin/colima completion fish) \
|
|
--zsh <($out/bin/colima completion zsh)
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = colima;
|
|
command = "HOME=$(mktemp -d) colima version";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Container runtimes with minimal setup";
|
|
homepage = "https://github.com/abiosoft/colima";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ aaschmid tricktron ];
|
|
};
|
|
}
|