4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
143 lines
3.7 KiB
Nix
143 lines
3.7 KiB
Nix
{ lib, stdenv, substituteAll, fetchFromGitHub, python3Packages, libunistring,
|
|
harfbuzz, fontconfig, pkgconfig, ncurses, imagemagick, xsel,
|
|
libstartup_notification, libGL, libX11, libXrandr, libXinerama, libXcursor,
|
|
libxkbcommon, libXi, libXext, wayland-protocols, wayland,
|
|
lcms2,
|
|
installShellFiles,
|
|
dbus,
|
|
Cocoa,
|
|
CoreGraphics,
|
|
Foundation,
|
|
IOKit,
|
|
Kernel,
|
|
OpenGL,
|
|
libcanberra,
|
|
libicns,
|
|
libpng,
|
|
python3,
|
|
zlib,
|
|
}:
|
|
|
|
with python3Packages;
|
|
buildPythonApplication rec {
|
|
pname = "kitty";
|
|
version = "0.19.3";
|
|
format = "other";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "kovidgoyal";
|
|
repo = "kitty";
|
|
rev = "v${version}";
|
|
sha256 = "0r49bybqy6c0n1lz6yc85py80wb40w757m60f5rszjf200wnyl6s";
|
|
};
|
|
|
|
buildInputs = [
|
|
harfbuzz
|
|
ncurses
|
|
lcms2
|
|
] ++ stdenv.lib.optionals stdenv.isDarwin [
|
|
Cocoa
|
|
CoreGraphics
|
|
Foundation
|
|
IOKit
|
|
Kernel
|
|
OpenGL
|
|
libpng
|
|
python3
|
|
zlib
|
|
] ++ stdenv.lib.optionals stdenv.isLinux [
|
|
fontconfig libunistring libcanberra libX11
|
|
libXrandr libXinerama libXcursor libxkbcommon libXi libXext
|
|
wayland-protocols wayland dbus
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
pkgconfig sphinx ncurses
|
|
installShellFiles
|
|
] ++ stdenv.lib.optionals stdenv.isDarwin [
|
|
imagemagick
|
|
libicns # For the png2icns tool.
|
|
];
|
|
|
|
propagatedBuildInputs = stdenv.lib.optional stdenv.isLinux libGL;
|
|
|
|
outputs = [ "out" "terminfo" ];
|
|
|
|
patches = [
|
|
./fix-paths.patch
|
|
];
|
|
|
|
# Causes build failure due to warning
|
|
hardeningDisable = stdenv.lib.optional stdenv.cc.isClang "strictoverflow";
|
|
|
|
dontConfigure = true;
|
|
|
|
buildPhase = if stdenv.isDarwin then ''
|
|
${python.interpreter} setup.py kitty.app \
|
|
--update-check-interval=0 \
|
|
--disable-link-time-optimization
|
|
make man
|
|
'' else ''
|
|
${python.interpreter} setup.py linux-package \
|
|
--update-check-interval=0 \
|
|
--egl-library='${stdenv.lib.getLib libGL}/lib/libEGL.so.1' \
|
|
--startup-notification-library='${libstartup_notification}/lib/libstartup-notification-1.so' \
|
|
--canberra-library='${libcanberra}/lib/libcanberra.so'
|
|
'';
|
|
|
|
checkInputs = [ pillow ];
|
|
|
|
checkPhase =
|
|
let buildBinPath =
|
|
if stdenv.isDarwin
|
|
then "kitty.app/Contents/MacOS"
|
|
else "linux-package/bin";
|
|
in
|
|
''
|
|
env PATH="${buildBinPath}:$PATH" ${python.interpreter} test.py
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out
|
|
${if stdenv.isDarwin then ''
|
|
mkdir "$out/bin"
|
|
ln -s ../Applications/kitty.app/Contents/MacOS/kitty "$out/bin/kitty"
|
|
mkdir "$out/Applications"
|
|
cp -r kitty.app "$out/Applications/kitty.app"
|
|
|
|
installManPage 'docs/_build/man/kitty.1'
|
|
'' else ''
|
|
cp -r linux-package/{bin,share,lib} $out
|
|
''}
|
|
wrapProgram "$out/bin/kitty" --prefix PATH : "$out/bin:${stdenv.lib.makeBinPath [ imagemagick xsel ncurses.dev ]}"
|
|
runHook postInstall
|
|
|
|
installShellCompletion --cmd kitty \
|
|
--bash <("$out/bin/kitty" + complete setup bash) \
|
|
--fish <("$out/bin/kitty" + complete setup fish) \
|
|
--zsh <("$out/bin/kitty" + complete setup zsh)
|
|
'';
|
|
|
|
postInstall = ''
|
|
terminfo_src=${if stdenv.isDarwin then
|
|
''"$out/Applications/kitty.app/Contents/Resources/terminfo"''
|
|
else
|
|
"$out/share/terminfo"}
|
|
|
|
mkdir -p $terminfo/share
|
|
mv "$terminfo_src" $terminfo/share/terminfo
|
|
|
|
mkdir -p $out/nix-support
|
|
echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/kovidgoyal/kitty";
|
|
description = "A modern, hackable, featureful, OpenGL based terminal emulator";
|
|
license = licenses.gpl3;
|
|
changelog = "https://sw.kovidgoyal.net/kitty/changelog.html";
|
|
platforms = platforms.darwin ++ platforms.linux;
|
|
maintainers = with maintainers; [ tex rvolosatovs Luflosi ];
|
|
};
|
|
}
|