d99321cf68
`gobjectIntrospection` provides a hook to fixup GI_TYPELIB_PATH. Before this change all blueman tools fail to start because they are unable to discover the Gtk3 libraries.
51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{ stdenv, lib, fetchurl, intltool, pkgconfig, pythonPackages, bluez, polkit, gtk3
|
|
, obex_data_server, xdg_utils, libnotify, dnsmasq, dhcp
|
|
, hicolor_icon_theme, librsvg, wrapGAppsHook, gobjectIntrospection
|
|
, withPulseAudio ? true, libpulseaudio }:
|
|
|
|
let
|
|
binPath = lib.makeBinPath [ xdg_utils dnsmasq dhcp ];
|
|
|
|
in stdenv.mkDerivation rec {
|
|
name = "blueman-${version}";
|
|
version = "2.0.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/blueman-project/blueman/releases/download/${version}/${name}.tar.xz";
|
|
sha256 = "03s305mbc57nl3sq5ywh9casz926k4aqnylgaidli8bmgz1djbg9";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
gobjectIntrospection intltool pkgconfig pythonPackages.cython
|
|
pythonPackages.wrapPython wrapGAppsHook
|
|
];
|
|
|
|
buildInputs = [ bluez gtk3 pythonPackages.python libnotify librsvg hicolor_icon_theme ]
|
|
++ pythonPath
|
|
++ lib.optional withPulseAudio libpulseaudio;
|
|
|
|
postPatch = lib.optionalString withPulseAudio ''
|
|
sed -i 's,CDLL(",CDLL("${libpulseaudio.out}/lib/,g' blueman/main/PulseAudioUtils.py
|
|
'';
|
|
|
|
pythonPath = with pythonPackages; [ dbus-python pygobject3 pycairo ];
|
|
|
|
propagatedUserEnvPkgs = [ obex_data_server ];
|
|
|
|
configureFlags = [ (lib.enableFeature withPulseAudio "pulseaudio") ];
|
|
|
|
postFixup = ''
|
|
makeWrapperArgs="--prefix PATH ':' ${binPath}"
|
|
# This mimics ../../../development/interpreters/python/wrap.sh
|
|
wrapPythonProgramsIn "$out/bin" "$out $pythonPath"
|
|
wrapPythonProgramsIn "$out/libexec" "$out $pythonPath"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = https://github.com/blueman-project/blueman;
|
|
description = "GTK+-based Bluetooth Manager";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ abbradar ];
|
|
};
|
|
}
|