7adb11cf58
https://codeberg.org/dnkl/fcft/releases/tag/2.4.6 https://codeberg.org/dnkl/fcft/releases/tag/2.5.0 Replace withHarfBuzz with withShapingTypes which allows us to more accurately represent the current feature flag situation upstream. Additionally test all non-default configurations via passthru.tests. Settings for shapingType: * `[ "grapheme" ]`: depend on HarfBuzz, like withHarfBuzz before * `[ "grapheme" "run" ]`: depend on HarfBuzz and utf8proc. This is the same as `[ "run" ]` at the moment which may change in the future. * `[]`: No text shaping support, no additional dependencies
63 lines
1.9 KiB
Nix
63 lines
1.9 KiB
Nix
{ stdenv, lib, fetchFromGitea, pkg-config, meson, ninja, scdoc
|
|
, freetype, fontconfig, pixman, tllist, check
|
|
# Text shaping methods to enable, empty list disables all text shaping.
|
|
# See `availableShapingTypes` or upstream meson_options.txt for available types.
|
|
, withShapingTypes ? [ "grapheme" "run" ]
|
|
, harfbuzz, utf8proc
|
|
, fcft # for passthru.tests
|
|
}:
|
|
|
|
let
|
|
# Needs to be reflect upstream meson_options.txt
|
|
availableShapingTypes = [
|
|
"grapheme"
|
|
"run"
|
|
];
|
|
|
|
# Courtesy of sternenseemann and FRidh, commit c9a7fdfcfb420be8e0179214d0d91a34f5974c54
|
|
mesonFeatureFlag = opt: b: "-D${opt}=${if b then "enabled" else "disabled"}";
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "fcft";
|
|
version = "2.5.0";
|
|
|
|
src = fetchFromGitea {
|
|
domain = "codeberg.org";
|
|
owner = "dnkl";
|
|
repo = "fcft";
|
|
rev = version;
|
|
sha256 = "0agqldh68hn898d3f6k99kjbz8had5j5k0jyvi71d4k9vhx8cy7c";
|
|
};
|
|
|
|
depsBuildBuild = [ pkg-config ];
|
|
nativeBuildInputs = [ pkg-config meson ninja scdoc ];
|
|
buildInputs = [ freetype fontconfig pixman tllist ]
|
|
++ lib.optionals (withShapingTypes != []) [ harfbuzz ]
|
|
++ lib.optionals (builtins.elem "run" withShapingTypes) [ utf8proc ];
|
|
checkInputs = [ check ];
|
|
|
|
mesonBuildType = "release";
|
|
mesonFlags = builtins.map (t:
|
|
mesonFeatureFlag "${t}-shaping" (lib.elem t withShapingTypes)
|
|
) availableShapingTypes;
|
|
|
|
doCheck = true;
|
|
|
|
passthru.tests = {
|
|
noShaping = fcft.override { withShapingTypes = []; };
|
|
onlyGraphemeShaping = fcft.override { withShapingTypes = [ "grapheme" ]; };
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://codeberg.org/dnkl/fcft";
|
|
changelog = "https://codeberg.org/dnkl/fcft/releases/tag/${version}";
|
|
description = "Simple library for font loading and glyph rasterization";
|
|
maintainers = with maintainers; [
|
|
fionera
|
|
sternenseemann
|
|
];
|
|
license = licenses.mit;
|
|
platforms = with platforms; linux;
|
|
};
|
|
}
|