2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
89 lines
2.2 KiB
Nix
89 lines
2.2 KiB
Nix
{ config, lib, options, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
name = "headphones";
|
|
|
|
cfg = config.services.headphones;
|
|
opt = options.services.headphones;
|
|
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
services.headphones = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc "Whether to enable the headphones server.";
|
|
};
|
|
dataDir = mkOption {
|
|
type = types.path;
|
|
default = "/var/lib/${name}";
|
|
description = lib.mdDoc "Path where to store data files.";
|
|
};
|
|
configFile = mkOption {
|
|
type = types.path;
|
|
default = "${cfg.dataDir}/config.ini";
|
|
defaultText = literalExpression ''"''${config.${opt.dataDir}}/config.ini"'';
|
|
description = lib.mdDoc "Path to config file.";
|
|
};
|
|
host = mkOption {
|
|
type = types.str;
|
|
default = "localhost";
|
|
description = lib.mdDoc "Host to listen on.";
|
|
};
|
|
port = mkOption {
|
|
type = types.ints.u16;
|
|
default = 8181;
|
|
description = lib.mdDoc "Port to bind to.";
|
|
};
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = name;
|
|
description = lib.mdDoc "User to run the service as";
|
|
};
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = name;
|
|
description = lib.mdDoc "Group to run the service as";
|
|
};
|
|
};
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
users.users = optionalAttrs (cfg.user == name) {
|
|
${name} = {
|
|
uid = config.ids.uids.headphones;
|
|
group = cfg.group;
|
|
description = "headphones user";
|
|
home = cfg.dataDir;
|
|
createHome = true;
|
|
};
|
|
};
|
|
|
|
users.groups = optionalAttrs (cfg.group == name) {
|
|
${name}.gid = config.ids.gids.headphones;
|
|
};
|
|
|
|
systemd.services.headphones = {
|
|
description = "Headphones Server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
serviceConfig = {
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
ExecStart = "${pkgs.headphones}/bin/headphones --datadir ${cfg.dataDir} --config ${cfg.configFile} --host ${cfg.host} --port ${toString cfg.port}";
|
|
};
|
|
};
|
|
};
|
|
}
|