f5fa5fa4d6
* pkgs: refactor needless quoting of homepage meta attribute A lot of packages are needlessly quoting the homepage meta attribute (about 1400, 22%), this commit refactors all of those instances. * pkgs: Fixing some links that were wrongfully unquoted in the previous commit * Fixed some instances
67 lines
2.3 KiB
Nix
67 lines
2.3 KiB
Nix
{ stdenv, fetchurl, pkgconfig, libpng, libjpeg, expat, libXaw
|
|
, yacc, libtool, fontconfig, pango, gd, xorg, gts, gettext, cairo
|
|
, ApplicationServices
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "2.32.0";
|
|
name = "graphviz-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.graphviz.org/pub/graphviz/ARCHIVE/${name}.tar.gz";
|
|
sha256 = "0ym7lw3xnkcgbk32vfmm3329xymca60gzn90rq6dv8887qqv4lyq";
|
|
};
|
|
|
|
buildInputs =
|
|
[ pkgconfig libpng libjpeg expat libXaw yacc libtool fontconfig
|
|
pango gd gts
|
|
] ++ stdenv.lib.optionals (xorg != null) [ xorg.xlibsWrapper xorg.libXrender ]
|
|
++ stdenv.lib.optionals stdenv.isDarwin [ ApplicationServices gettext ];
|
|
|
|
CPPFLAGS = stdenv.lib.optionalString (stdenv.system == "x86_64-darwin") "-I${cairo.dev}/include/cairo";
|
|
|
|
configureFlags =
|
|
[ "--with-pngincludedir=${libpng.dev}/include"
|
|
"--with-pnglibdir=${libpng.out}/lib"
|
|
"--with-jpegincludedir=${libjpeg.dev}/include"
|
|
"--with-jpeglibdir=${libjpeg.out}/lib"
|
|
"--with-expatincludedir=${expat.dev}/include"
|
|
"--with-expatlibdir=${expat.out}/lib"
|
|
"--with-ltdl-include=${libtool}/include"
|
|
"--with-ltdl-lib=${libtool.lib}/lib"
|
|
"--with-cgraph=no"
|
|
"--with-sparse=no"
|
|
]
|
|
++ stdenv.lib.optional (xorg == null) "--without-x";
|
|
|
|
hardeningDisable = [ "fortify" ];
|
|
|
|
preBuild = ''
|
|
sed -e 's@am__append_5 *=.*@am_append_5 =@' -i lib/gvc/Makefile
|
|
'';
|
|
|
|
# "command -v" is POSIX, "which" is not
|
|
postInstall = ''
|
|
sed -i 's|`which lefty`|"'$out'/bin/lefty"|' $out/bin/dotty
|
|
sed -i 's|which|command -v|' $out/bin/vimdot
|
|
'';
|
|
|
|
meta = {
|
|
homepage = http://www.graphviz.org/;
|
|
description = "Open source graph visualization software";
|
|
|
|
longDescription = ''
|
|
Graphviz is open source graph visualization software. Graph
|
|
visualization is a way of representing structural information as
|
|
diagrams of abstract graphs and networks. It has important
|
|
applications in networking, bioinformatics, software engineering,
|
|
database and web design, machine learning, and in visual
|
|
interfaces for other technical domains.
|
|
'';
|
|
|
|
platforms = stdenv.lib.platforms.linux ++ stdenv.lib.platforms.darwin;
|
|
maintainers = with stdenv.lib.maintainers; [ bjornfor raskin ];
|
|
inherit version;
|
|
branch = "2.32";
|
|
};
|
|
}
|