4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
44 lines
1.4 KiB
Nix
44 lines
1.4 KiB
Nix
{ stdenv, lib, fetchzip, autoPatchelfHook, xorg, gtk2, gnome2, gtk3, nss, alsaLib, udev, unzip, wrapGAppsHook }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "cypress";
|
|
version = "6.0.0";
|
|
|
|
src = fetchzip {
|
|
url = "https://cdn.cypress.io/desktop/${version}/linux-x64/cypress.zip";
|
|
sha256 = "0hii7kp48ba07gsd521wwl288p808xr2wqgk1iidxkzj2v6g71by";
|
|
};
|
|
|
|
# don't remove runtime deps
|
|
dontPatchELF = true;
|
|
|
|
nativeBuildInputs = [ autoPatchelfHook wrapGAppsHook ];
|
|
|
|
buildInputs = with xorg; [
|
|
libXScrnSaver libXdamage libXtst
|
|
] ++ [
|
|
nss gtk2 alsaLib gnome2.GConf gtk3 unzip
|
|
];
|
|
|
|
runtimeDependencies = [ (lib.getLib udev) ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin $out/opt/cypress
|
|
cp -vr * $out/opt/cypress/
|
|
# Let's create the file binary_state ourselves to make the npm package happy on initial verification.
|
|
# Cypress now verifies version by reading bin/resources/app/package.json
|
|
mkdir -p $out/bin/resources/app
|
|
printf '{"version":"%b"}' $version > $out/bin/resources/app/package.json
|
|
# Cypress now looks for binary_state.json in bin
|
|
echo '{"verified": true}' > $out/binary_state.json
|
|
ln -s $out/opt/cypress/Cypress $out/bin/Cypress
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Fast, easy and reliable testing for anything that runs in a browser";
|
|
homepage = "https://www.cypress.io";
|
|
license = licenses.mit;
|
|
platforms = ["x86_64-linux"];
|
|
maintainers = with maintainers; [ tweber mmahut ];
|
|
};
|
|
}
|