9dee19030b
This change does three things: 1. Increases nghttp2's version from 1.20.0 to 1.24.0 2. Adds a `bin` output 3. Enables building of nghttp2's suite of applications
50 lines
1.6 KiB
Nix
50 lines
1.6 KiB
Nix
{ stdenv, fetchurl, pkgconfig
|
|
|
|
# Optional Dependencies
|
|
, openssl ? null, libev ? null, zlib ? null, c-ares ? null
|
|
, enableHpack ? false, jansson ? null
|
|
, enableAsioLib ? false, boost ? null
|
|
, enableGetAssets ? false, libxml2 ? null
|
|
, enableJemalloc ? false, jemalloc ? null
|
|
}:
|
|
|
|
assert enableHpack -> jansson != null;
|
|
assert enableAsioLib -> boost != null;
|
|
assert enableGetAssets -> libxml2 != null;
|
|
assert enableJemalloc -> jemalloc != null;
|
|
|
|
let inherit (stdenv.lib) optional; in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "nghttp2-${version}";
|
|
version = "1.24.0";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/nghttp2/nghttp2/releases/download/v${version}/nghttp2-${version}.tar.bz2";
|
|
sha256 = "18ys6p39yvm9wjjzhhlw35c9m8f5gf4dk9jbshibj19q4js1pnv9";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "dev" "lib" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ openssl libev zlib c-ares ]
|
|
++ optional enableHpack jansson
|
|
++ optional enableAsioLib boost
|
|
++ optional enableGetAssets libxml2
|
|
++ optional enableJemalloc jemalloc;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = [ "--with-spdylay=no" "--disable-examples" "--disable-python-bindings" "--enable-app" ]
|
|
++ optional enableAsioLib "--enable-asio-lib --with-boost-libdir=${boost}/lib";
|
|
|
|
#doCheck = true; # requires CUnit ; currently failing at test_util_localtime_date in util_test.cc
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://nghttp2.org/;
|
|
description = "A C implementation of HTTP/2";
|
|
license = licenses.mit;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ wkennington ];
|
|
};
|
|
}
|