2579942661
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/feh/versions. These checks were done: - built on NixOS - /nix/store/81pgn9ww37hp996d45xrm9wbl6z8wfc3-feh-2.26.4/bin/feh passed the binary check. - /nix/store/81pgn9ww37hp996d45xrm9wbl6z8wfc3-feh-2.26.4/bin/.feh-wrapped passed the binary check. - 2 of 2 passed binary check by having a zero exit code. - 0 of 2 passed binary check by having the new version present in output. - found 2.26.4 with grep in /nix/store/81pgn9ww37hp996d45xrm9wbl6z8wfc3-feh-2.26.4 - directory tree listing: https://gist.github.com/13a57ff84731135ece55fe0c99093a7d - du listing: https://gist.github.com/dda79019b9ca9069b6dd9dbb773bf602
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{ stdenv, fetchurl, makeWrapper
|
|
, xorg, imlib2, libjpeg, libpng
|
|
, curl, libexif, perlPackages }:
|
|
|
|
with stdenv.lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "feh-${version}";
|
|
version = "2.26.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://feh.finalrewind.org/${name}.tar.bz2";
|
|
sha256 = "15a7hjg7xwj1hsw3c5k18psvvmbqgn4g79qq03bsvibzl4kqakq7";
|
|
};
|
|
|
|
outputs = [ "out" "man" "doc" ];
|
|
|
|
nativeBuildInputs = [ makeWrapper xorg.libXt ]
|
|
++ optionals doCheck [ perlPackages.TestCommand perlPackages.TestHarness ];
|
|
|
|
buildInputs = [ xorg.libX11 xorg.libXinerama imlib2 libjpeg libpng curl libexif ];
|
|
|
|
makeFlags = [
|
|
"PREFIX=$(out)" "exif=1"
|
|
] ++ optional stdenv.isDarwin "verscmp=0";
|
|
|
|
postBuild = ''
|
|
pushd man
|
|
make
|
|
popd
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram "$out/bin/feh" --prefix PATH : "${libjpeg.bin}/bin" \
|
|
--add-flags '--theme=feh'
|
|
install -D -m 644 man/*.1 $out/share/man/man1
|
|
'';
|
|
|
|
checkPhase = ''
|
|
PERL5LIB="${perlPackages.TestCommand}/lib/perl5/site_perl" make test
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = {
|
|
description = "A light-weight image viewer";
|
|
homepage = "https://feh.finalrewind.org/";
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.viric maintainers.willibutz ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|