397daef205
systemd is a fairly large dependency, and it doesn't appear to be necessary in all circumstances - e.g. when openvpn is not run as a systemd service (as is usually the case when it is run in a Docker container). This change makes the dependency on systemd optional, controlled by a new argument `useSystemd`. The default behaviour remains the same as it was before this change: enabled only on Linux systems. For me, this change reduces the size of my container image (dominated by the closure of openvpn) from about 110 MB to 45 MB. Version 2: rename argument to `useSystemd` (was `systemdSupport`), and rebase onto master
51 lines
1.6 KiB
Nix
51 lines
1.6 KiB
Nix
{ stdenv, fetchurl, iproute, lzo, openssl, pam, pkgconfig
|
|
, useSystemd ? stdenv.isLinux, systemd ? null
|
|
, pkcs11Support ? false, pkcs11helper ? null,
|
|
}:
|
|
|
|
assert useSystemd -> (systemd != null);
|
|
assert pkcs11Support -> (pkcs11helper != null);
|
|
|
|
with stdenv.lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "openvpn-${version}";
|
|
version = "2.4.4";
|
|
|
|
src = fetchurl {
|
|
url = "http://swupdate.openvpn.net/community/releases/${name}.tar.xz";
|
|
sha256 = "102an395nv8l7qfx3syydzhmd9xfbycd6gvwy0h2kjz8w67ipkcn";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ lzo openssl ]
|
|
++ optionals stdenv.isLinux [ pam iproute ]
|
|
++ optional useSystemd systemd
|
|
++ optional pkcs11Support pkcs11helper;
|
|
|
|
configureFlags = optionals stdenv.isLinux [
|
|
"--enable-iproute2"
|
|
"IPROUTE=${iproute}/sbin/ip" ]
|
|
++ optional useSystemd "--enable-systemd"
|
|
++ optional pkcs11Support "--enable-pkcs11"
|
|
++ optional stdenv.isDarwin "--disable-plugin-auth-pam";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/doc/openvpn/examples
|
|
cp -r sample/sample-config-files/ $out/share/doc/openvpn/examples
|
|
cp -r sample/sample-keys/ $out/share/doc/openvpn/examples
|
|
cp -r sample/sample-scripts/ $out/share/doc/openvpn/examples
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "A robust and highly flexible tunneling application";
|
|
homepage = http://openvpn.net/;
|
|
downloadPage = "https://openvpn.net/index.php/open-source/downloads.html";
|
|
license = stdenv.lib.licenses.gpl2;
|
|
maintainers = [ stdenv.lib.maintainers.viric ];
|
|
platforms = stdenv.lib.platforms.unix;
|
|
updateWalker = true;
|
|
};
|
|
}
|