ede5720a0d
* Improves the comments of `lib/flake-version-info.nix` and drops the `__`-prefix from the filename. * `lib'` -> `lib0` in `nixpkgs/lib`. * Drop the declaration of `trivial.version` in the overlay because this declaration already uses the final expressions of `versionSuffix` and `release` now. * No need to fall back to `self.lastModified` anymore, this was a workaround for pre2.4 Nix. Co-authored-by: Robert Hensing <robert@roberthensing.nl> Co-authored-by: Silvan Mosberger <contact@infinisil.com>
77 lines
2.6 KiB
Nix
77 lines
2.6 KiB
Nix
# Experimental flake interface to Nixpkgs.
|
|
# See https://github.com/NixOS/rfcs/pull/49 for details.
|
|
{
|
|
description = "A collection of packages for the Nix package manager";
|
|
|
|
outputs = { self }:
|
|
let
|
|
jobs = import ./pkgs/top-level/release.nix {
|
|
nixpkgs = self;
|
|
};
|
|
|
|
libVersionInfoOverlay = import ./lib/flake-version-info.nix self;
|
|
lib = (import ./lib).extend libVersionInfoOverlay;
|
|
|
|
forAllSystems = lib.genAttrs lib.systems.flakeExposed;
|
|
in
|
|
{
|
|
overlays.setLibVersionInfo = final: prev: {
|
|
lib = prev.lib.extend libVersionInfoOverlay;
|
|
};
|
|
|
|
lib = lib.extend (final: prev: {
|
|
|
|
nixos = import ./nixos/lib { lib = final; };
|
|
|
|
nixosSystem = args:
|
|
import ./nixos/lib/eval-config.nix (
|
|
args // { inherit (self) lib; } // lib.optionalAttrs (! args?system) {
|
|
# Allow system to be set modularly in nixpkgs.system.
|
|
# We set it to null, to remove the "legacy" entrypoint's
|
|
# non-hermetic default.
|
|
system = null;
|
|
}
|
|
);
|
|
});
|
|
|
|
checks.x86_64-linux.tarball = jobs.tarball;
|
|
|
|
htmlDocs = {
|
|
nixpkgsManual = jobs.manual;
|
|
nixosManual = (import ./nixos/release-small.nix {
|
|
nixpkgs = self;
|
|
}).nixos.manual.x86_64-linux;
|
|
};
|
|
|
|
# The "legacy" in `legacyPackages` doesn't imply that the packages exposed
|
|
# through this attribute are "legacy" packages. Instead, `legacyPackages`
|
|
# is used here as a substitute attribute name for `packages`. The problem
|
|
# with `packages` is that it makes operations like `nix flake show
|
|
# nixpkgs` unusably slow due to the sheer number of packages the Nix CLI
|
|
# needs to evaluate. But when the Nix CLI sees a `legacyPackages`
|
|
# attribute it displays `omitted` instead of evaluating all packages,
|
|
# which keeps `nix flake show` on Nixpkgs reasonably fast, though less
|
|
# information rich.
|
|
legacyPackages = forAllSystems (system: import ./. {
|
|
inherit system;
|
|
overlays = [ self.overlays.setLibVersionInfo ];
|
|
});
|
|
|
|
nixosModules = {
|
|
notDetected = ./nixos/modules/installer/scan/not-detected.nix;
|
|
|
|
/*
|
|
Make the `nixpkgs.*` configuration read-only. Guarantees that `pkgs`
|
|
is the way you initialize it.
|
|
|
|
Example:
|
|
|
|
{
|
|
imports = [ nixpkgs.nixosModules.readOnlyPkgs ];
|
|
nixpkgs.pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
}
|
|
*/
|
|
readOnlyPkgs = ./nixos/modules/misc/nixpkgs/read-only.nix;
|
|
};
|
|
};
|
|
}
|