4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
44 lines
1.6 KiB
Nix
44 lines
1.6 KiB
Nix
{ lib, stdenv, buildPackages, fetchurl, zlib, fetchpatch }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "kexec-tools";
|
|
version = "2.0.20";
|
|
|
|
src = fetchurl {
|
|
urls = [
|
|
"mirror://kernel/linux/utils/kernel/kexec/${pname}-${version}.tar.xz"
|
|
"http://horms.net/projects/kexec/kexec-tools/${pname}-${version}.tar.xz"
|
|
];
|
|
sha256 = "1j7qlhxk1rbv9jbj8wd6hb7zl8p2mp29ymrmccgmsi0m0dzhgn6s";
|
|
};
|
|
|
|
hardeningDisable = [ "format" "pic" "relro" "pie" ];
|
|
|
|
# Prevent kexec-tools from using uname to detect target, which is wrong in
|
|
# cases like compiling for aarch32 on aarch64
|
|
configurePlatforms = [ "build" "host" ];
|
|
configureFlags = [ "BUILD_CC=${buildPackages.stdenv.cc.targetPrefix}cc" ];
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ];
|
|
buildInputs = [ zlib ];
|
|
|
|
patches = [
|
|
# fix build on i686
|
|
# See: https://src.fedoraproject.org/rpms/kexec-tools/c/cb1e5463b5298b064e9b6c86ad6fe3505fec9298
|
|
(fetchpatch {
|
|
name = "kexec-tools-2.0.20-fix-broken-multiboot2-buliding-for-i386.patch";
|
|
url = "https://src.fedoraproject.org/rpms/kexec-tools/raw/cb1e5463b5298b064e9b6c86ad6fe3505fec9298/f/kexec-tools-2.0.20-fix-broken-multiboot2-buliding-for-i386.patch";
|
|
sha256 = "1kzmcsbhwfdgxlc5s88ir0n494phww1j16yk0z42x09qlkxxkg0l";
|
|
})
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "http://horms.net/projects/kexec/kexec-tools";
|
|
description = "Tools related to the kexec Linux feature";
|
|
platforms = platforms.linux;
|
|
badPlatforms = [
|
|
"riscv64-linux" "riscv32-linux"
|
|
"sparc-linux" "sparc64-linux"
|
|
];
|
|
license = licenses.gpl2;
|
|
};
|
|
}
|