f110d54c72
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/safeeyes/versions. These checks were done: - built on NixOS - ran ‘/nix/store/gzc1ivdll8xp7mx7ii0l9xkhfjzw872a-safeeyes-2.0.5/bin/safeeyes -h’ got 0 exit code - ran ‘/nix/store/gzc1ivdll8xp7mx7ii0l9xkhfjzw872a-safeeyes-2.0.5/bin/safeeyes --help’ got 0 exit code - found 2.0.5 with grep in /nix/store/gzc1ivdll8xp7mx7ii0l9xkhfjzw872a-safeeyes-2.0.5 - directory tree listing: https://gist.github.com/748ac5c50858dc7c1d5736104b8970b3
71 lines
1.8 KiB
Nix
71 lines
1.8 KiB
Nix
{ lib, python3Packages, gobjectIntrospection, libappindicator-gtk3, libnotify, gtk3, gnome3, xprintidle-ng, wrapGAppsHook, gdk_pixbuf, shared-mime-info, librsvg
|
|
}:
|
|
|
|
let inherit (python3Packages) python buildPythonApplication fetchPypi;
|
|
|
|
in buildPythonApplication rec {
|
|
name = "${pname}-${version}";
|
|
pname = "safeeyes";
|
|
version = "2.0.5";
|
|
namePrefix = "";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "1q52ncqn18wb3d42dzsm7lh301w6g053a685i1cnismvp86amvfl";
|
|
};
|
|
|
|
buildInputs = [
|
|
gtk3
|
|
gobjectIntrospection
|
|
gnome3.defaultIconTheme
|
|
gnome3.adwaita-icon-theme
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
wrapGAppsHook
|
|
];
|
|
|
|
propagatedBuildInputs = with python3Packages; [
|
|
Babel
|
|
psutil
|
|
xlib
|
|
pygobject3
|
|
dbus-python
|
|
|
|
libappindicator-gtk3
|
|
libnotify
|
|
xprintidle-ng
|
|
];
|
|
|
|
# patch smartpause plugin
|
|
postPatch = ''
|
|
sed -i \
|
|
-e 's!xprintidle!xprintidle-ng!g' \
|
|
safeeyes/plugins/smartpause/plugin.py
|
|
|
|
sed -i \
|
|
-e 's!xprintidle!xprintidle-ng!g' \
|
|
safeeyes/plugins/smartpause/config.json
|
|
'';
|
|
|
|
preFixup = ''
|
|
gappsWrapperArgs+=(
|
|
--prefix XDG_DATA_DIRS : "${gdk_pixbuf}/share"
|
|
--prefix XDG_DATA_DIRS : "${shared-mime-info}/share"
|
|
--prefix XDG_DATA_DIRS : "${librsvg}/share"
|
|
|
|
# safeeyes images
|
|
--prefix XDG_DATA_DIRS : "$out/lib/${python.libPrefix}/site-packages/usr/share"
|
|
)
|
|
'';
|
|
|
|
doCheck = false; # no tests
|
|
|
|
meta = {
|
|
homepage = http://slgobinath.github.io/SafeEyes;
|
|
description = "Protect your eyes from eye strain using this simple and beautiful, yet extensible break reminder. A Free and Open Source Linux alternative to EyeLeo";
|
|
license = lib.licenses.gpl3;
|
|
maintainers = with lib.maintainers; [ srghma ];
|
|
platforms = lib.platforms.all;
|
|
};
|
|
}
|