41 lines
1.2 KiB
Nix
41 lines
1.2 KiB
Nix
{ stdenv, fetchurl, pkgconfig, gnutls, jansson, liburcu, lmdb, libcap_ng, libidn
|
|
, systemd, nettle, libedit }:
|
|
|
|
# Note: ATM only the libraries have been tested in nixpkgs.
|
|
stdenv.mkDerivation rec {
|
|
name = "knot-dns-${version}";
|
|
version = "2.4.0";
|
|
|
|
src = fetchurl {
|
|
url = "http://secure.nic.cz/files/knot-dns/knot-${version}.tar.xz";
|
|
sha256 = "0y9nhp9lfmxv4iy1xg7l4lfxv4168qhag26wwg0dbi0zjpkd790b";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "dev" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
gnutls jansson liburcu libidn
|
|
nettle libedit
|
|
# without sphinx &al. for developer documentation
|
|
]
|
|
# Use embedded lmdb there for now, as detection is broken on Darwin somehow.
|
|
++ stdenv.lib.optionals stdenv.isLinux [ libcap_ng systemd lmdb ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
CFLAGS = [ "-DNDEBUG" ];
|
|
|
|
#doCheck = true; problems in combination with dynamic linking
|
|
|
|
postInstall = ''rm -r "$out"/var'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Authoritative-only DNS server from .cz domain registry";
|
|
homepage = https://knot-dns.cz;
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.vcunat ];
|
|
};
|
|
}
|
|
|