fef4b62657
The patch is from the following Gentoo bug: https://bugs.gentoo.org/show_bug.cgi?id=523326#c24 Built successfully against Linux 3.18.36, 4.4.16 and 4.7.0. Signed-off-by: aszlig <aszlig@redmoonstudios.org> Cc: @phreedom, @vcunat
53 lines
1.5 KiB
Nix
53 lines
1.5 KiB
Nix
{ stdenv, fetchurl, kernel }:
|
|
|
|
let
|
|
version = "6.30.223.271";
|
|
hashes = {
|
|
i686-linux = "1kaqa2dw3nb8k23ffvx46g8jj3wdhz8xa6jp1v3wb35cjfr712sg";
|
|
x86_64-linux = "1gj485qqr190idilacpxwgqyw21il03zph2rddizgj7fbd6pfyaz";
|
|
};
|
|
|
|
arch = stdenv.lib.optionalString (stdenv.system == "x86_64-linux") "_64";
|
|
tarballVersion = stdenv.lib.replaceStrings ["."] ["_"] version;
|
|
tarball = "hybrid-v35${arch}-nodebug-pcoem-${tarballVersion}.tar.gz";
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "broadcom-sta-${version}-${kernel.version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.broadcom.com/docs/linux_sta/${tarball}";
|
|
sha256 = hashes.${stdenv.system};
|
|
};
|
|
|
|
patches = [
|
|
./i686-build-failure.patch
|
|
./license.patch
|
|
./linux-4.7.patch
|
|
./null-pointer-fix.patch
|
|
./gcc.patch
|
|
];
|
|
|
|
makeFlags = "KBASE=${kernel.dev}/lib/modules/${kernel.modDirVersion}";
|
|
|
|
unpackPhase = ''
|
|
sourceRoot=broadcom-sta
|
|
mkdir "$sourceRoot"
|
|
tar xvf "$src" -C "$sourceRoot"
|
|
'';
|
|
|
|
installPhase = ''
|
|
binDir="$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
|
|
docDir="$out/share/doc/broadcom-sta/"
|
|
mkdir -p "$binDir" "$docDir"
|
|
cp wl.ko "$binDir"
|
|
cp lib/LICENSE.txt "$docDir"
|
|
'';
|
|
|
|
meta = {
|
|
description = "Kernel module driver for some Broadcom's wireless cards";
|
|
homepage = http://www.broadcom.com/support/802.11/linux_sta.php;
|
|
license = stdenv.lib.licenses.unfreeRedistributable;
|
|
maintainers = with stdenv.lib.maintainers; [ phreedom vcunat ];
|
|
platforms = stdenv.lib.platforms.linux;
|
|
};
|
|
}
|